Packard Bell - Multimedia…D & Packard Bell Library/Packard Bell Master CD.iso/bu/k/555597/pbtools/backup/pbfix.bat

DOS Batch File | 1995-02-07 | 11KB | 334 lines

@echo off
if (%MPARM%)==() goto VERSION
if %MPARM%==ALL goto SKIPVERSION

:Version
@echo    Packard Bell PBFix -- Configuration Restore Utility -- Version 2.7.95a
@echo ═════════════════════════════════════════════════════════════════════════════

:SKIPVERSION
ctty nul
set copycmd=/y
SET TEMPATH=%PATH%
PATH=%1
SET ONE=%PATH%
PATH=%TEMPATH%
SET TEMPATH=
SET PARM= NULL

if (%ONE%)==() goto HELP
if %ONE% == HELP goto HELP
if %ONE% == WINDOWS goto R_WIN
if %ONE% == ROOT goto R_ROOT
if %ONE% == PRODIGY goto R_PROD
if %ONE% == DISKIMAG goto R_DISKIMAG
if %ONE% == ALL goto R_ALL
if %ONE% == PBNAV goto R_PBNAV
goto HELP


:R_WIN       REM**************************************************

  REM ** check for existence of files in backup sub-directory **

  if not exist c:\pbtools\backup\*.ini set PARM= R_WIN
  if not exist c:\pbtools\backup\*.grp set PARM= R_WIN
  if not exist c:\windows\*.ini set PARM= R_WINA
  if %PARM%== R_WIN goto NOT_HERE
  if %PARM%== R_WINA goto NOT_HERE

  REM ** copy files to correct directory **

  ctty con
  @echo Please wait while the original Windows is being restored!
  ctty nul
  if exist c:\windows\*.ini copy c:\windows\*.ini c:\windows\*.fxi
  if exist c:\pbtools\backup\*.ini copy c:\pbtools\backup\*.ini c:\windows
  if exist c:\windows\*.grp copy c:\windows\*.grp c:\windows\*.fxg
  if exist c:\pbtools\backup\*.grp copy c:\pbtools\backup\*.grp c:\windows
  if exist c:\pbtools\backup\*.drv copy c:\pbtools\backup\*.drv c:\windows\system
  if exist c:\pbtools\backup\*.hlp copy c:\pbtools\backup\*.hlp c:\windows\system

  if %MPARM%== ALL goto WINCONTINUE

  ctty con
  @echo Process complete!
  @echo.
  @echo ╒════════════════════════════════════════════════════════════════════╕
  @echo │ The existing *.ini files in the C:\WINDOWS sub-directory have been │
  @echo │ renamed with an *.fxi extension and the existing *.grp files have  │
  @echo │ been renamed with an *.fxg extension.                              │
  @echo ╘════════════════════════════════════════════════════════════════════╛
  ctty nul

  :WINCONTINUE

goto END


:R_ROOT      REM**************************************************

  REM ** check for existence of files in backup sub-directory **

  if not exist c:\pbtools\backup\autoexec.bat set PARM= R_ROOT
  if not exist c:\pbtools\backup\config.sys set PARM= R_ROOT
  if %PARM%== R_ROOT goto NOT_HERE

  REM ** copy files to correct directory **

  ctty con
  @echo Please wait while the original Root is being restored!
  ctty nul
  if exist c:\autoexec.bat copy c:\autoexec.bat c:\autoexec.fx_
  if exist c:\pbtools\backup\autoexec.bat copy c:\pbtools\backup\autoexec.bat c:\
  if exist c:\config.sys copy c:\config.sys c:\config.fx_
  if exist c:\pbtools\backup\config.sys copy c:\pbtools\backup\config.sys c:\
  if not exist c:\jp.bat if exist c:\pbtools\backup\jp.bat copy c:\pbtools\backup\jp.bat c:\ /v

  IF %MPARM%== ALL goto RCONTINUE

  ctty con
  @echo Process complete!
  @echo. ╒═════════════════════════════════════════════════════════════════╕
  @echo  │ The existing AUTOEXEC.BAT file has been renamed to AUTOEXEC.FX_ │
  @echo  │ and the CONFIG.SYS file has been renamed to CONFIG.FX_.         │
  @echo  ╘═════════════════════════════════════════════════════════════════╛
  ctty nul

  :RCONTINUE

goto END

:R_PBNAV      REM**************************************************

  REM ** check for existence of files in backup sub-directory **

  if not exist c:\pbtools\backup\navigate.ini set PARM= R_PBNAV
  if %PARM%== R_PBNAV goto NOT_HERE

  REM ** copy files to correct directory **

  ctty con
  @echo Please wait while the original Navigator INI files
  @echo are being restored!
  ctty nul
  if exist c:\pbnav30\pbnew\navigate.ini copy c:\pbnav30\pbnew\navigate.ini c:\pbnav30\pbnew\navigate.fx_
  if exist c:\pbtools\backup\navigate.ini copy c:\pbtools\backup\navigate.ini c:\pbnav30\pbnew
  if exist c:\pbnav30\kidspace\kidspace.ini copy c:\pbnav30\kidspace\kidspace.ini c:\pbnav30\kidspace\kidspace.fx_
  if exist c:\pbtools\backup\kidspace.ini copy c:\pbtools\backup\kidspace.ini c:\pbnav30\kidspace
  if exist c:\pbnav30\kidspace\*.inf del c:\pbnav30\kidspace\*.inf
  if exist c:\pbnav30\docmgr\docmgr.ini copy c:\pbnav30\docmgr\docmgr.ini c:\pbnav30\docmgr\docmgr.fx_
  if exist c:\pbtools\backup\docmgr.ini copy c:\pbtools\backup\docmgr.ini c:\pbnav30\docmgr
  if exist c:\pbnav30\docmgr\*.inf del c:\pbnav30\docmgr\*.inf
  if exist c:\pbtools\backup\acessory.ico copy c:\pbtools\backup\acessory.ico c:\pbnav30\pbnew
  if exist c:\pbtools\backup\printer.ico copy c:\pbtools\backup\printer.ico c:\pbnav30\pbnew
  if exist c:\pbtools\backup\megarace.ico copy c:\pbtools\backup\megarace.ico c:\megarace

  IF %MPARM%== ALL goto PBCONTINUE

  ctty con
  @echo Process complete!
  @echo.╒══════════════════════════════════════════════════════════════════════════╕
  @echo │ These files have been renamed as follows:                                │
  @echo.│                                                                          │
  @echo │ C:\PBNAV30\PBNEW\NAVIGATE.INI      to   C:\PBNAV30\PBNEW\NAVIGATE.FX_    │
  @echo │ C:\PBNAV30\KIDSPACE\KIDSPACE.INI   to   C:\PBNAV30\KIDSPACE\KIDSPACE.FX_ │
  @echo │ C:\PBNAV30\DOCMGR\DOCMGR.INI       to   C:\PBNAV30\DOCMGR\DOCMGR.FX_     │
  @echo ╘══════════════════════════════════════════════════════════════════════════╛
  @echo.
  ctty nul

  :PBCONTINUE

goto END



:R_PROD      REM**************************************************

  REM ** check for existence of files in backup sub-directory **

  if not exist c:\pbtools\backup\prodigy.* set PARM= R_PROD
  if not exist c:\prodigy\*.* if exist c:\pbtools\backup\prodigy.* md c:\prodigy
  if %PARM%== R_PROD goto NOT_HERE

  REM ** copy files to correct directory **

  ctty con
  @echo Please wait while the original Prodigy\Windows files
  @echo are being restored!
  ctty nul
  if exist c:\pbtools\backup\prodigy.ini copy c:\pbtools\backup\prodigy.ini c:\prodigy

  IF %MPARM%== ALL goto PRODCONTINUE

  ctty con
  @echo Process complete!
  ctty nul

  :PRODCONTINUE

goto END


:R_DISKIMAG      REM**************************************************

  REM ** check for existence of files in backup sub-directory **

  if not exist c:\pbtools\backup\diskimag.ini set PARM= R_DISKIMAG
  if not exist c:\diskimag\*.* if exist c:\pbtools\backup\diskimag.ini md c:\diskimag
  if %PARM%== R_DISKIMAG goto NOT_HERE

  REM ** copy files to correct directory **

  ctty con
  @echo Please wait while the original Disk Image INI file
  @echo is being restored!
  ctty nul
  if exist c:\pbtools\backup\diskimag.ini if exist c:\diskimag\diskimag.ini ren c:\diskimag\diskimag.ini *.fxi
  if exist c:\pbtools\backup\diskimag.ini copy c:\pbtools\backup\diskimag.ini c:\diskimag
  if exist c:\pbtools\backup\vbrun200.dll if not exist c:\windows\vbrun200.dll copy c:\pbtools\backup\vbrun200.dll c:\windows
  if exist c:\pbtools\backup\vbrun300.dll if not exist c:\windows\vbrun300.dll copy c:\pbtools\backup\vbrun300.dll c:\windows

  IF %MPARM%== ALL goto DICONTINUE

  ctty con
  @echo Process complete!
  @echo.
  @echo The existing C:\DISKIMAG\DISKIMAG.INI file has been
  @echo renamed to DISKIMAG.FXI.
  @echo.
  ctty nul

  :DICONTINUE

goto END


:R_ALL       REM**************************************************

  SET MPARM=%ONE%
  for %%A in (WINDOWS ROOT PRODIGY DISKIMAG PBNAV) DO call pbfix %%A
  SET MPARM=

  ctty con
  @echo Process Complete!
  ctty nul



goto END


:HELP        REM**************************************************

  ctty con

  @ECHO.
  @ECHO    Packard Bell PBFix -- Configuration Restore Utility
  @ECHO ═════════════════════════════════════════════════════════════════════════════
  @ECHO Syntax:
  @ECHO        PBFIX option
  @ECHO      Option:      Files restored...
  @ECHO        WINDOWS      *.INI, *.GRP, and printer drivers
  @ECHO        ROOT         CONFIG.SYS & AUTOEXEC.BAT
  @ECHO        PRODIGY      PRODIGY.INI
  @ECHO        DISKIMAG     The DISKIMAG.INI file and VBRUN300.DLL
  @ECHO        PBNAV        All Navigator .INI files
  @ECHO        ALL          All of the above
  @ECHO.
  if exist c:\dos\more.com goto SCROLL_README

  Goto END

  :SCROLL_README
  @echo Press CTRL-C to stop here, or for additional information...
  PAUSE
  type c:\pbtools\backup\readme.doc | more
  ctty nul

goto END


:NOT_HERE   REM**************************************************

  if %MPARM%==ALL ctty nul
  if %MPARM%!==! ctty con

  if %PARM%== R_WIN     goto MESS0
  if %PARM%== R_WINA    goto MESS0A

  if %PARM%== R_ROOT    goto MESS1
  if %PARM%== R_PROD    goto MESS2

  if %PARM%== R_DISKIMAG goto MESS5B

  if %PARM%== R_PBNAV   goto MESS8

goto END


:MESS0      REM**************************************************

  @ECHO The original Windows *.INI or *.GRP files were not found in the
  @echo C:\PBTOOLS\BACKUP sub-directory!
  @echo.

goto END


:MESS0A     REM**************************************************

  @ECHO Windows must be installed BEFORE using PBFIX!
  @echo 

goto END


:MESS1      REM**************************************************

  @ECHO The root directory restore files were not found in the
  @echo C:\PBTOOLS\BACKUP sub-directory!
  @echo 

goto END


:MESS2      REM**************************************************

  @ECHO The Prodigy back-up files were not found in the
  @echo C:\pbtools\backup sub-directory!
  @echo 
  @echo Prodigy may not have been included with this system!
  @echo.

goto END


:MESS5B     REM**************************************************

  @echo The Disk Image program back-up files were not found in the
  @echo C:\PBTOOLS\BACKUP sub-directory!
  @echo 
  @echo Disk Image may not have been included with this system!
  @echo.

goto END


:MESS8      REM**************************************************

  @ECHO The PACKARD BELL NAVIGATOR back-up files were not found in the
  @ECHO C:\pbtools\backup sub-directory!
  @echo 
  @echo NAVIGATOR may not have been included with this system!
  @echo.

goto END

:END        REM**************************************************

SET PARM=
SET ONE=
ctty con